BasicGame square_size=30
    SpriteSet
        floor > Immovable img=oryx/grass autotiling=True hidden=True
        water > Immovable color=BLUE img=oryx/seaWater
        catapult > Immovable
            southfacing > orientation=DOWN  color=RED img=oryx/bookDown
            northfacing > orientation=UP  color=ORANGE img=oryx/bookUp
            eastfacing  > orientation=RIGHT color=YELLOW img=oryx/bookRight
            westfacing  > orientation=LEFT color=YELLOW img=oryx/bookLeft
        avatar >
            moving > MovingAvatar img=oryx/vampire1
            bullet > MissileAvatar img=oryx/bat1
                north  > orientation=UP color=RED
                south  > orientation=DOWN color=ORANGE
                east   > orientation=RIGHT color=YELLOW
                west   > orientation=LEFT color=GREEN
        goal  > Immovable color=GREEN img=oryx/dooropen1 portal=True
        wall > Immovable img=oryx/bush5
    LevelMapping
        . > water floor
        0 > eastfacing floor
        1 > southfacing floor
        2 > northfacing floor
        3 > westfacing floor
        g > goal floor
        A > moving floor
        _ > floor
        w > wall floor
    InteractionSet

        bullet wall > transformTo stype=moving
        moving wall > stepBack
        moving water > killSprite

        avatar catapult    > attractGaze prob=1

        avatar westfacing  > transformTo stype=west
        avatar eastfacing  > transformTo stype=east
        avatar southfacing > transformTo stype=south
        avatar northfacing > transformTo stype=north

        catapult avatar    > killSprite scoreChange=1
        goal avatar        > killSprite

    TerminationSet
        SpriteCounter stype=goal    limit=0 win=True
        SpriteCounter stype=avatar  limit=0 win=False
